flake/modules/home/terminal/hr/default.nix

{
  pkgs,
  lib,
  config,
  ...
}: let
  cfg = config.mods.terminal;

  test-port = "5436";
  prod-port = "5437";
in {
  options.mods.terminal.hr.enable = lib.mkEnableOption "Hefring (Work Tooling)";

  config = lib.mkIf cfg.hr.enable {
    programs.starship.settings.custom.project_id = {
      command = "if echo \"$PROJECT_ID\" | grep -q \"prod\"; then printf \"\\033[1;33m \\033[1;34m$PROJECT_ID\\033[0m\"; else printf \"\\033[1;34m$PROJECT_ID\\033[0m\"; fi";
      when = "test -n \"$PROJECT_ID\"";
      format = "on $output ";
    };

    programs.zsh.initExtra =
      ''
        export MK2_TEST_SQL_INSTANCE_USER=gijs
        export MK2_TEST_SQL_INSTANCE_PASSWORD="$(cat ${config.sops.secrets.google-db-test.path})"
        export MK2_TEST_SQL_INSTANCE_PORT=${test-port}
        export MK2_TEST_SQL_INSTANCE_HOST=localhost
        export MK2_PROD_SQL_INSTANCE_USER=gijs
        export MK2_PROD_SQL_INSTANCE_PASSWORD="$(cat ${config.sops.secrets.google-db-prod.path})"
        export MK2_PROD_SQL_INSTANCE_HOST=localhost
        export MK2_PROD_SQL_INSTANCE_PORT=${prod-port}
      ''
      + builtins.readFile ./hr.sh;

    systemd.user.services = let
      proxy-service = name: port: {
        "google-db-proxy-${name}" = {
          Unit = {
            Description = "Google Cloud SQL Proxy (${name})";
            After = ["network.target"];
          };
          Service = {
            Type = "simple";
            Environment = [
              "GOOGLE_APPLICATION_CREDENTIALS=${config.home.homeDirectory}/.config/gcloud/application_default_credentials.json"
            ];
            ExecStart = "${pkgs.google-cloud-sql-proxy}/bin/cloud-sql-proxy mk2-${name}:europe-west1:mk2-${name}-sql-instance -p ${port}";
            Restart = "always";
          };
          Install = {
            WantedBy = ["default.target"];
          };
        };
      };
    in
proxy-service "test" test-port
       // proxy-service "prod" prod-port;
  };
}