flake/modules/nixos/impermanence.nix

{
  pkgs,
  lib,
  config,
  ...
}:
with lib; {
  options.mods.impermanence.enable = mkEnableOption "enables impermanence";

  config = mkIf config.mods.impermanence.enable {
    environment.persistence."/persist" = {
      directories = ["/var/lib/nixos" "/var/lib/systemd/coredump"];
      files = ["/var/lib/sops-nix/key.txt" "/etc/machine-id"];
    };

    boot.initrd.systemd.services.rollback = {
      description = "Roll back root btrfs subvolume";
      wantedBy = ["initrd.target"];
      after = ["cryptsetup.target"];
      before = ["sysroot.mount"];
      unitConfig.DefaultDependencies = "no";
      serviceConfig.Type = "oneshot";
      script = ''
        mkdir /btrfs_tmp
        mount /dev/mapper/crypted /btrfs_tmp
        if [[ -e /btrfs_tmp/root ]]; then
            mkdir -p /btrfs_tmp/old_roots
            timestamp=$(date --date="@$(stat -c %Y /btrfs_tmp/root)" "+%Y-%m-%-d_%H:%M:%S")
            mv /btrfs_tmp/root "/btrfs_tmp/old_roots/$timestamp"
        fi

        delete_subvolume_recursively() {
            IFS=$'\n'
            for i in $(btrfs subvolume list -o "$1" | cut -f 9- -d ' '); do
                delete_subvolume_recursively "/btrfs_tmp/$i"
            done
            btrfs subvolume delete "$1"
        }

        for i in $(find /btrfs_tmp/old_roots/ -maxdepth 1 -mtime +30); do
            delete_subvolume_recursively "$i"
        done

        btrfs subvolume create /btrfs_tmp/root
        umount /btrfs_tmp
      '';
    };
  };
}